用多媒体库 Bass.dll 播放 mp3 [5] - 设置与获取音量、相位

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    OpenDialog1: TOpenDialog;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    TrackBar1: TTrackBar;
    TrackBar2: TTrackBar;
    Label1: TLabel;
    Label2: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure TrackBar1Change(Sender: TObject);
    procedure TrackBar2Change(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses Bass;

var
  hs: HSTREAM;  {流句柄}

procedure TForm1.FormCreate(Sender: TObject);
begin
  TrackBar1.ShowSelRange := False;
  TrackBar1.Min := 0;
  TrackBar1.Max := 40;
  TrackBar1.Position := TrackBar1.Max;

  TrackBar2.ShowSelRange := False;
  TrackBar2.Min := -20;
  TrackBar2.Max := 20;
  TrackBar2.Position := 0;

  if HiWord(BASS_GetVersion) <> BASSVERSION then
    MessageBox(0, '"Bass.dll" 文件版本不合适! ', nil, MB_ICONERROR);

  if not BASS_Init(-1, 44100, 0, 0, nil) then
    ShowMessage('初始化错误');
end;

{打开}
procedure TForm1.Button1Click(Sender: TObject);
var
  Mp3Path: AnsiString;
begin
  BASS_StreamFree(hs);

  OpenDialog1.Filter := 'Mp3 文件(*.mp3)|*.mp3|Wav 文件(*.wav)|*wav';
  if OpenDialog1.Execute then
    Mp3Path := AnsiString(OpenDialog1.FileName);

  hs := BASS_StreamCreateFile(False, PAnsiChar(Mp3Path), 0, 0, 0);

  if hs < BASS_ERROR_ENDED then
    Text := '打开失败'
  else begin
    TrackBar1Change(nil);
    TrackBar2Change(nil);
    Text := string(Mp3Path);
  end;
end;

{播放}
procedure TForm1.Button2Click(Sender: TObject);
begin
  BASS_ChannelPlay(hs, False);
end;

{暂停}
procedure TForm1.Button3Click(Sender: TObject);
begin
  BASS_ChannelPause(hs);
end;

{设置和获取音量}
procedure TForm1.TrackBar1Change(Sender: TObject);
var
  vol: Single;
begin
  BASS_ChannelSetAttribute(hs, BASS_ATTRIB_VOL, TrackBar1.Position / TrackBar1.Max);
  BASS_ChannelGetAttribute(hs, BASS_ATTRIB_VOL, vol);
  Label1.Caption := Format('当前音量值: %f', [vol]);
end;

{设置和获取相位}
procedure TForm1.TrackBar2Change(Sender: TObject);
var
  pan: Single;
begin
  BASS_ChannelSetAttribute(hs, BASS_ATTRIB_PAN, TrackBar2.Position / TrackBar2.Max);
  BASS_ChannelGetAttribute(hs, BASS_ATTRIB_PAN, pan);
  Label2.Caption := Format('当前相位值: %f', [pan]);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  BASS_Free;
end;

end.

 
 
 
  unit Unit1;

i